***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Apr 26, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt MB1H60AL-AU A K 
.param
+vc0 = 8.150e-10	 vc1 = 1.029e-10	vc2 = 2.215e-10		 vc3 = 8.471e-2
+tc1 = 2.052e-1		 tc2 = 5.411e-2		tc3 = 6.552e-2		 tc4 = 4.611e-2	
d1 A K sbd
g1 K A value = {(vc0+vc1*v(K,A))*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+vc2*exp(vc3*v(K,A))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
.model sbd d
***** flag parameter *****
+level = 1
***** dc model parameter *****
+ is = 3.102e-10	   n = 0.935		  rs = 7.124e-2		 ikf = 0.065
+ibv = 0.5e-3		 nbv = 1		  bv = 66
***** capacitance parameter *****
+cjo = 1.360e-10	   m = 4.494e-1		  vj = 5.154e-1
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = 0.891		 xti = 1
+trs1 = 1.105e-3	trs2 = -3.225e-5	tikf = -4e-3		
.ends MB1H60AL-AU
*$